PowerappsでCollectionを操作する。（Patch,UpdateIf,Remove)

Powerappsのコレクションを編集用のギャラリーから更新する方法

1. 作成：Patch
2. 更新：Patch、Updateif
3. 一括更新：Patch
4. 削除：Remove
5. 一括削除：Clear

色々やり方はあるのですが、特に一括（for allで更新するところ）が結構はまってしまったので備忘録として記事にしました。

今回テスト用に作ったのは以下のアプリ

1. コレクションを編集するためのギャラリー
2. コレクションを参照するためのテーブル
3. 編集用のギャラリーに空白レコードを挿入するアイコン（Patchでコレクションにからレコードを作成しています。）
4. コレクションを削除するアイコン
5. ギャラリーでの編集を一括で更新するボタン（Patchバージョン）
6. ギャラリーでの編集を一括で更新するボタン（updateifバージョン）
7. ギャラリーで選択されている行を削除するアイコン
8. ギャラリーで選択されている行のみ更新するアイコン（Patchバージョン）
9. ギャラリーで選択されている行のみ更新するアイコン（Updateifバージョン）

③編集用のギャラリーに空白レコードを挿入

Set(
    Index,
    Index + 1
);
Collect(
    datacollection,
    {
        Index: Index,
        ischosen: false,
        name: "",
        phone: "",
        comments: ""
    }
)

これはPatchではなくて単純にCollect関数で新規レコードをコレクションに追加しています。

④コレクションを削除する

Clear(datacollection);
Set(
    Index,
    0
);
Set(
    Index,
    Index + 1
);
Collect(
    datacollection,
    {
        Index: Index,
        ischosen: false,
        name: "",
        phone: "",
        comments: ""
    }
)

 

Clear関数でコレクションを削除しています。※今回のテーマとは関連しないです。

コレクションをクリアした時点で新規のレコードを１レコード挿入する実装としています。

⑤ギャラリーでの編集を一括で更新するボタン

ForAll(
    RenameColumns(
        Gallery_for_Edit.AllItems,
        "Index",
        "tmpIndex"
    ),
    Patch(
        datacollection,
        LookUp(
            datacollection,
            Index = tmpIndex
        ),
        {
            name: TextInput_name.Text,
            phone: TextInput_telephone.Text,
            comments: TextInput_comment.Text
        }
    )
)

これが一番今回でハマったポイントです。

⑥ギャラリーでの編集を一括で更新する

ForAll(
    RenameColumns(
        Gallery_for_Edit.AllItems,
        "Index",
        "tmpIndex"
    ),
    UpdateIf(
        datacollection,
        Index = tmpIndex,
        {
            name: TextInput_name.Text,
            phone: TextInput_telephone.Text,
            comments: TextInput_comment.Text
        }
    )
)

これはPatchの代わりにUpdateIf関数を利用した場合です。UpdateIfで書いた方が条件はシンプルに書けますが、PatchでもUpdateIfでもどちらでもいいでしょう。

⑦ギャラリーで選択されている行を削除する

Remove(
    datacollection,
    First(
        Filter(
            datacollection,
            Index = ThisItem.Index
        )
    )
)

レコードの削除はRemove関数で実装しています。

これはシンプルなのであまり悩む要素がありませんでした。

⑧ギャラリーで選択されている行のみ更新する

 

Patch(
    datacollection,
    ThisItem,
    {
        name: TextInput_name.Text,
        phone: TextInput_telephone.Text,
        comments: TextInput_comment.Text
    }
);

これはシンプルなのであまり悩む要素がありません。

⑨ギャラリーで選択されている行のみ更新する

UpdateIf(
    datacollection,
    Index = Gallery_for_Edit.Selected.Index,
    {
        name: TextInput_name.Text,
        phone: TextInput_telephone.Text,
        comments: TextInput_comment.Text
    }
)